Data: 17 czerwca 2023

**Dokumentacja techniczna**

**aplikacji wspomagającej zarządzenie funduszem nagród w przedsiębiorstwie**

Autor: Joanna Misztal-Jarząbek

Spis treści

[Wstęp - Przeznaczenie aplikacji 3](#_Toc137894869)

[Wygląd aplikacji 3](#_Toc137894870)

[1. Panel sterowania aplikacją 3](#_Toc137894871)

[2. Arkusz: Podział podstawowy 4](#_Toc137894872)

[3. Arkusz: Tabela źródłowa 6](#_Toc137894873)

[4. Arkusz: Nieobecności pracowników 8](#_Toc137894874)

[5. Arkusz: Wyszukiwarka 9](#_Toc137894875)

[6. Arkusz: Tabela dla jednostek 9](#_Toc137894876)

[7. Arkusz: Tabela zbiorcza 10](#_Toc137894877)

[8. Arkusz: Listy płac 10](#_Toc137894878)

[9. Arkusz: Tabele pomocnicze 11](#_Toc137894879)

[Zastosowane makra 12](#_Toc137894880)

[1. Microsoft Excel Objects -Ten\_skoroszyt 13](#_Toc137894881)

[2. Forms – UserForm1 13](#_Toc137894882)

[3. Modules 15](#_Toc137894883)

[1. Moduł: DokumentacjaTechniczna 15](#_Toc137894884)

[2. Moduł: DokumentacjaUżytkownika 15](#_Toc137894885)

[3. Moduł: ListyPłac 16](#_Toc137894886)

[4. Moduł: RaportyWord 19](#_Toc137894887)

[5. Moduł: Statystyki 22](#_Toc137894888)

[6. Moduł: TabelaZbiorcza 26](#_Toc137894889)

[7. Moduł: Tabele 27](#_Toc137894890)

[8. Moduł UserForm 31](#_Toc137894891)

[9. Moduł: Wyszukiwarka 31](#_Toc137894892)

# Wstęp - Przeznaczenie aplikacji

Aplikacja wspomagająca zarządzanie funduszem nagród w przedsiębiorstwie służy do automatyzacji procesu podziału funduszu nagród oraz wymiany korespondencji pomiędzy pracownikiem obsługującym aplikację a odpowiednio: jednostkami organizacyjnymi, komórką płac, komórką kadr, zarządem przedsiębiorstwa.

Podział nagród podlega ustalonym kryteriom przyznawania nagród pracownikom zatrudnionym w jednostkach organizacyjnych przedsiębiorstwa związanym m.in. z absencją pracowniczą w badanym okresie. Nagrody dla pracowników przyznawane są w systemie kwartalnym.

**Dane osobowe użyte w aplikacji wygenerowane zostały poprzez stronę** [**https://random-data-generator.com/generator-losowych-imion-i-nazwisk/**](https://random-data-generator.com/generator-losowych-imion-i-nazwisk/)**. Jakakolwiek zbieżność z prawdziwymi nazwiskami jest przypadkowa.**

Aplikacja w znaczący sposób optymalizuje zarządzanie funduszem nagród, efektywnie skraca czas poświęcony na podział funduszu oraz zebranie danych niezbędnych do przyznania nagrody.

Zachęcam do zapoznania się z możliwościami jakie oferuje przygotowane przeze mnie narzędzie.

Łączę wyrazy szacunku, Joanna Misztal-Jarząbek

# Wygląd aplikacji

Aplikacja znajduje się w skoroszycie „zarządzanie funduszem nagród”. Narzędzie zawiera 8 arkuszy opisanych poniżej. Do skoroszytu załączone są dwa szablony dla aplikacji Word oraz Power Point które stanowią integralną część sprawnie działającej aplikacji. Załącznikiem do skoroszytu są dwa pliki tekstowe: Podręcznik dla użytkownika oraz Dokumentacja techniczna.

## Panel sterowania aplikacją

Panel sterowania aplikacją znajduje się w arkuszu „Podział podstawowy”. Arkusz zawiera 6 przycisków odpowiedzialnych za wywołanie odpowiednich makr:

* Generuj pisma z raportem dla jednostek – makro Raport\_Word
* Generuj tabele dla jednostek – makro Tabele
* Utwórz tabelę zbiorczą – makro TabelaZbiorcza
* Generuj listy płac – makro ListyPlac
* Wyszukiwarka – makro Wyszukiwarka
* Statystyki – makro Statystyki

oraz 2 przyciski wywołujące pliki aplikacji Word:

* Podręcznik użytkownika
* Dokumentacja techniczna

Obraz zawierający tekst, zrzut ekranu, Prostokąt, Czcionka

Opis wygenerowany automatycznie

## Arkusz: Podział podstawowy

Arkusz stanowi narzędzie do podziału funduszu nagród na poszczególne jednostki organizacyjne.

Zawarte w nim są tabele bazują na tabeli źródłowej z arkusza „Tabela źródłowa”. Wysokość funduszu nagród ustalana jest indywidualnie dla każdego kolejnego kwartału w danym roku. Z funduszu wyodrębnia się kwotę 8%, którą pozostawia się do dyspozycji zarządu przedsiębiorstwa z przeznaczeniem na nagrody dodatkowe dla szczególnie wyróżniających się pracowników. Kwota na nagrodę dla dyrektora, zastępców dyrektora, głównego księgowego, kierowników, zastępców kierowników, głównych ekspertów, starszych ekspertów, głównych specjalistów, ekspertów i specjalistów liczone są w oparciu o określony dla każdego z wymienionych stanowisk współczynnik według poniższego wzoru:

*przeciętna kwota nagrody x (S2 x 1,25 + S3 x 1,5 + S4 x 1,75 + S5 x 2 + S6 x 2,5 + S7 x 3 + S8 x 3,5)*

gdzie:

S2 oznacza etaty ekspertów i specjalistów,

S3 oznacza etaty starszych ekspertów i głównych specjalistów

S4 oznacza etaty głównych ekspertów

S5 oznacza etaty zastępców kierowników

S6 oznacza etaty kierowników

S7 oznacza etaty zastępców dyrektora i głównego księgowego

S8 oznacza etat dyrektora

Przez przeciętną kwotę nagrody należy rozumieć wielkość stanowiącą podstawę wyliczeń części funduszu ustalaną według wzoru:

*przeciętna kwota = fundusz nagród pomniejszony o 8% ogólnej wartości*

*nagrody (S1+S2x1,25+S3x1,5+S4x1,75+S5x2+S6x2,5+S7x3+S8x3,5)*

gdzie poza symbolami wyjaśnionymi powyżej użyty jest dodatkowy symbol S1 oznaczający etaty osób zajmujących stanowiska pozostałe, dla których współczynnik przeliczeń wynosi 1.

Kwotę przeznaczoną na nagrody pracowników których etaty oznaczone zostały symbolem S1 liczy się według wzoru:

*przeciętna kwota nagrody x S1*

W arkuszu zastosowano następujące formuły:

* Obliczenie liczby etatów określonych danym symbolem (od S8 do S1):

=SUMA.WARUNKÓW(Tabela2[Wymiar etatu]; Tabela2[Status pracownika];"S8"), itp.

* Podział funduszu nagród na poszczególne jednostki organizacyjne:

=LICZ.WARUNKI(Tabela2[Jednostka organizacyjna];"101";Tabela2[Status pracownika];"S8")\*$D19\*$B$13, itp.

Obraz zawierający tekst, zrzut ekranu, Równolegle, diagram

Opis wygenerowany automatycznie

## Arkusz: Tabela źródłowa

Arkusz zawiera dane bazowe dotyczące poszczególnych pracowników uprawnionych do nagród. Dane pracowników generowane będą z systemu kadrowo-płacowego oraz obejmują:

* Nazwisko i imię pracownika
* Jednostkę organizacyjną
* Symbol komórki organizacyjnej
* Stanowisko służbowe
* Wymiar etatu
* Wyliczenie średniej kwoty nagrody na danym stanowisku
* Status pracownika
* Współczynnik dla stanowiska
* Wyliczenie dni roboczych absencji z tytułu wyszczególnionych nieobecności
* Informacja o uprawnieniu do nagrody w przypadku 50% przepracowanego nominalnego czasu pracy, określonego w dniach roboczych w rozpatrywanym kwartale.

W arkuszu zastosowano następujące formuły:

* Przypisanie średniej kwoty nagrody do stanowiska z danej kategorii:

=JEŻELI(D7="dyrektor ";'Podział podstawowy'!$F$19;JEŻELI(LUB(D7="zastępca dyrektora ";D7="główny księgowy");'Podział podstawowy'!$F$20;JEŻELI(D7="kierownik";'Podział podstawowy'!$F$24;JEŻELI(D7="zastępca kierownika";'Podział podstawowy'!$F$25;JEŻELI(D7="główny ekspert";'Podział podstawowy'!$F$26;JEŻELI(LUB(D7="starszy ekspert";D7="główny specjalista");'Podział podstawowy'!$F$27;JEŻELI(LUB(D7="ekspert";D7="specjalista");'Podział podstawowy'!$F$28;'Podział podstawowy'!$F$29)))))))

* Określenie statusu pracownika (od S1 do S8)

=JEŻELI(D7="dyrektor ";"S8";JEŻELI(LUB(D7="zastępca dyrektora ";D7="główny księgowy");"S7";JEŻELI(D7="kierownik";"S6";JEŻELI(D7="zastępca kierownika";"S5";JEŻELI(D7="główny ekspert";"S4";JEŻELI(LUB(D7="starszy ekspert";D7="główny specjalista");"S3";JEŻELI(LUB(D7="ekspert";D7="specjalista");"S2";"S1")))))))

* Przypisanie współczynnika dla danego stanowiska

=JEŻELI(G7="S1";1;JEŻELI(G7="S2";1,25;JEŻELI(G7="S3";1,5;JEŻELI(G7="S4";1,75;JEŻELI(G7="S5";2;JEŻELI(G7="S6";2,5;JEŻELI(G7="S7";3;JEŻELI(G7="S8";3,5))))))))

* Wyznaczenie liczby dni absencji dla poszczególnych pracowników

=JEŻELI.BŁĄD(WYSZUKAJ.PIONOWO([@[Nazwisko i imię pracownika]];Tabela3;9;FAŁSZ);0)

* Ustalenie uprawnienia do nagrody na podstawie absencji pracowniczej

=JEŻELI([@[Liczba dni roboczych absencji z tytułu urlopu bezpłatnego, wychowawczego, choroby, opieki nad chorym, pobierania zasiłków, świadczeń rehabilitacyjnych]]>=Nieobecności!$B$28;"NIE UPRAWNIONY";

**Dane osobowe użyte w aplikacji wygenerowane zostały poprzez stronę** [**https://random-data-generator.com/generator-losowych-imion-i-nazwisk/**](https://random-data-generator.com/generator-losowych-imion-i-nazwisk/)**. Jakakolwiek zbieżność z prawdziwymi nazwiskami jest przypadkowa.**

Obraz zawierający tekst, zrzut ekranu, Czcionka, numer

Opis wygenerowany automatycznie

## Arkusz: Nieobecności pracowników

Arkusz zawiera dane dotyczące nieobecności pracowników w badanym kwartale. Nagroda przyznawana jest jedynie tym pracownikom, którzy we wskazanym kwartale świadczyli pracę przez co najmniej 50 % nominalnego czasu pracy określonego w dniach roboczych. Dane obejmują:

* Nazwisko i imię pracownika
* Jednostkę organizacyjną
* Symbol komórki organizacyjnej
* Stanowisko służbowe
* Wymiar etatu
* Rodzaj nieobecności
* Wskazanie okresu nieobecności ( w zakresie od … do…)
* Wyliczenie ilości dni roboczych absencji

W arkuszu zastosowano następujące formuły:

* Wyliczenie liczby dni roboczych na podstawie okresu nieobecności:

=DNI.ROBOCZE.NIESTAND([@[Nieobecność od dnia]];[@[Nieobecność do dnia]];1;$D$27:$D$30)

**Dane osobowe użyte w aplikacji wygenerowane zostały poprzez stronę** [**https://random-data-generator.com/generator-losowych-imion-i-nazwisk/**](https://random-data-generator.com/generator-losowych-imion-i-nazwisk/)**. Jakakolwiek zbieżność z prawdziwymi nazwiskami jest przypadkowa.**

Obraz zawierający tekst, zrzut ekranu, numer, Równolegle

Opis wygenerowany automatycznie

## Arkusz: Wyszukiwarka

Arkusz zawiera dane bazowe tożsame z danymi z arkusza „Tabela zbiorcza”, dotyczące poszczególnych pracowników uprawnionych do nagród. Zastosowane formanty formularza umożliwiają wyszukiwanie w bazie pracowników według kryteriów:

* Jednostka organizacyjna
* Symbol jednostki organizacyjnej
* Stanowisko służbowe

Obraz zawierający tekst, zrzut ekranu, oprogramowanie, Strona internetowa

Opis wygenerowany automatycznie

## Arkusz: Tabela dla jednostek

Arkusz zawiera szablon na bazie którego kopiowane są dane bazowe z „Tabeli źródłowej” dotyczące poszczególnych pracowników uprawnionych do nagród. Nagrody mają charakter uznaniowy i mogą zostać przydzielone według kryteriów określonych w tabelach dla jednostek.


Dane pobierane są dla każdej jednostki organizacyjnej odrębnie oraz zapisywane jako tabela aplikacji Excel w utworzonym katalogu „Tabele dla jednostek”. Wygenerowane tabele przesyłane są do poszczególnych jednostek organizacyjnych celem uzupełnienia danych.

Obraz zawierający tekst, linia, Czcionka, numer

Opis wygenerowany automatycznie

## Arkusz: Tabela zbiorcza

Arkusz pobiera odesłane przez jednostki organizacyjne tabele wygenerowane w katalogu „Tabele dla jednostek”. Pobrane tabele są uzupełnione o niezbędne dane dotyczące spełnienia poszczególnych kryteriów, uzasadnienie decyzji o przyznaniu nagrody oraz kwotę przydzielonej nagrody przez bezpośredniego przełożonego. Dane w tabeli zbiorczej zapisywane są kolejności rosnącej od pierwszej do ostatniej jednostki a następnie przekazywane do dyrektora celem akceptacji lub korekty kwoty nagrody proponowanej przez bezpośredniego przełożonego.



## Arkusz: Listy płac

Arkusz zawiera szablon na bazie którego kopiowane są dane z „Tabeli zbiorczej” dotyczące przydzielonej przez dyrektora nagrody kwartalnej. Dla każdego pracownika odrębnie wyszczególniona jest kwota przydzielonej nagrody. Dane pobierane są dla każdej jednostki organizacyjnej odrębnie oraz zapisywane jako tabela aplikacji Excel w utworzonym katalogu „Listy płac”. Wygenerowane tabele przesyłane są do komórki płac celem wszczęcia procedury wypłaty nagrody poszczególnym pracownikom.



## Arkusz: Tabele pomocnicze

Arkusz zawiera tabele przestawne oraz zbudowane na ich podstawie wykresy i statystyki opisowe dla badanych danych. Wykresy i statystyki wykorzystane są w aplikacji Power Point celem prezentacji wyników analizy przed zarządem firmy. Zakres i kryteria prezentowanych danych można dowolnie modyfikować względem oczekiwań końcowych odbiorców.

Obraz zawierający tekst, zrzut ekranu, oprogramowanie, linia

Opis wygenerowany automatycznie

Obraz zawierający tekst, numer, Czcionka, oprogramowanie

Opis wygenerowany automatycznie

Obraz zawierający tekst, numer, Czcionka, linia

Opis wygenerowany automatycznie

# Zastosowane makra

W aplikacji zastosowano 9 makr w 8 modułach. Poszczególne makra przypisane są do odpowiadających ich przycisków w arkuszu „Podział podstawowy”.

Obraz zawierający tekst, elektronika, zrzut ekranu, oprogramowanie

Opis wygenerowany automatycznie

## Microsoft Excel Objects -Ten\_skoroszyt

Makro zastosowane w tym Obiekcie przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA oraz TWORZENIE PROFESJONALNYCH APLIKACJI (PROJEKTOWANIE INTERFEJSU UŻYTKOWNIKA). Obsługa zdarzeń.

Makro przy otwieraniu skoroszytu wywołuje wyświetlanie UserForm1.

Private Sub Workbook\_Open()

UserForm1.Show

End Sub

## Forms – UserForm1

Makro zastosowane w tym Formie przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA oraz TWORZENIE PROFESJONALNYCH APLIKACJI (PROJEKTOWANIE INTERFEJSU UŻYTKOWNIKA). Zaawansowane formularze użytkownika. Makro służy do wczytania właściwości wyświetlonego UserForma.

Private Sub UserForm\_Initialize()

'Rozmiar okna dialogowego i położenie formantów jest dostosowywany do rozmiarów Excela

'Rozmiar formularza UserForm

With Me

.Height = Application.Height

.Width = Application.Width

.Left = Application.Left

.Top = Application.Top

End With

' Ustawia opóźnione zdarzenie zamknięcia formularza po 3 sekundach

Application.OnTime Now + TimeValue("00:00:06"), "ZamknijFormularz"

End Sub

Obraz zawierający tekst, zrzut ekranu, oprogramowanie, Oprogramowanie multimedialne

Opis wygenerowany automatycznie

## Modules

### Moduł: DokumentacjaTechniczna

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI).

Sub DokumentacjaTechniczna()

'makro wywołuje dokument "Dokumentacja Techniczna"

Dim WordA As Word.Application 'aplikacja Word

Dim PlikW As Word.Document 'plik Worda

Const PlikSzablon = "Dokumentacja Techniczna.docx" 'nazwa pliku Worda z szablonem

'Wczytanie nowego obiektu będącego aplikacją Worda

Set WordA = New Word.Application

WordA.Visible = True 'widoczna aplikacja Word

'Otwarcie szablonu (pliku Word)

Set PlikW = WordA.Documents.Open(ThisWorkbook.Path & "\" & PlikSzablon)

End Sub

### Moduł: DokumentacjaUżytkownika

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI).

Sub DokumentacjaUzytkownika()

'makro wywołuje dokument "Dokumentacja Użytkownika"

Dim WordA As Word.Application 'aplikacja Word

Dim PlikW As Word.Document 'plik Worda

Const PlikSzablon = "Dokumentacja Użytkownika.docx" 'nazwa pliku Worda z szablonem

'Wczytanie nowego obiektu będącego aplikacją Worda

Set WordA = New Word.Application

WordA.Visible = True 'widoczna aplikacja Word

'Otwarcie szablonu (pliku Word)

Set PlikW = WordA.Documents.Open(ThisWorkbook.Path & "\" & PlikSzablon)

End Sub

### Moduł: ListyPłac

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI). Operacje na plikach i katalogach oraz na podstawie rejestratora makr.

Makro generuje listy płac na bazie utworzonej tabeli zbiorczej w arkuszu „Tabela zbiorcza”. Tabele dla poszczególnych jednostek organizacyjnych generowane są i zapisywane w osobnych plikach.

'FileSystemObjecy

'Referencje: Tools --> References... --> Windows Script Host Object Model

'...........................................................................................

Sub ListyPlac()

‘Makro generuje listy płac dla poszczególnych jednostek

Dim FSO As Object

Dim Folder As Object

Dim NowyFolder As String

Dim Katalog As String

Const PlikSzablon = "Tabela zbiorcza" 'nazwa arkusza Excela z szablonem

Katalog = ThisWorkbook.Path & "\Listy płac\_" & Format(Date, "yyyy-mm-dd") 'lokalizacja zapisywanych raportów

Application.DisplayAlerts = False ' ukrycie alertów

Application.ScreenUpdating = False ' wyłączenie aktualizacji ekranu

'Utworzenie katalogu do zapisu pliku

Set FSO = CreateObject("Scripting.FileSystemObject")

If Not FSO.FolderExists(Katalog) Then

' Katalog nie istnieje, a więc tworzenie katalogu

FSO.CreateFolder Katalog

End If

Dim ArkuszZrodlowy As Worksheet 'arkusz źródłowy

Dim ArkuszDocelowy As Worksheet 'arkusz w którym dane zostaną zapisane

Dim ZakresZrodlowy As Range 'zakres danych w arkuszu źródłowym

Dim ZakresDocelowy As Range 'zakres danych w arkuszu w którym dane zostaną zapisane

Dim OstatniWiersz As Long 'wyznaczenie ostatniego wiersza

' Ustawienie arkuszy źródłowego i docelowego

Set ArkuszZrodlowy = ThisWorkbook.Worksheets("Tabela zbiorcza")

Set ArkuszDocelowy = ThisWorkbook.Worksheets("Listy płac")

' Określenie ostatniego wiersza

OstatniWiersz = ArkuszZrodlowy.Cells(ArkuszZrodlowy.Rows.Count, 1).End(xlUp).Row

'Znalezienie unikalnych wartości w kolumnie 2 (jednostka organizacyjna)

Dim Jednostki As Range

'ustalenie unikalnych wartości z kolumny "B" i skopiowanie ich do zakresu od komórki "O6"

ArkuszZrodlowy.Range("B5:B" & OstatniWiersz).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=ArkuszZrodlowy.Range("O5"), Unique:=True

'Przypisanie skopiowanych wartości do zmiennej Jednostki

Set Jednostki = ArkuszZrodlowy.Range("O7:O21") 'zakres danych do pobrania

Dim Jednostka As Range 'poszczególne jednostki dla któych generowane będą tabele

Dim Filtr As Range 'filtr

Dim OstatniWierszDocelowy As Long 'zmienna do wyznaczenia ostatniego wiersza w arkuszu docelowym

For Each Jednostka In Jednostki 'generowanie tabel dla poszczególnych jednostek

' Czyszczenie danych z arkusza docelowego(o ile istnieja)

If ArkuszDocelowy.Range("A7") <> "" Then

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).ClearContents ' wyczyszczenie zawartości

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).Borders.LineStyle = xlNone ' wyczyszczenie obramowania

End If

' Ustawienie filtra dla jednostki

ArkuszZrodlowy.Range("A5:M" & OstatniWiersz).AutoFilter Field:=2, Criteria1:=Jednostka.Value

' Skopiowanie widocznych danych dla jednostki

OstatniWierszDocelowy = ArkuszDocelowy.Cells(Rows.Count, 1).End(xlUp).Row + 1 'wyznaczenie ostatniego wiersza w arkuszu docelowym

Set ZakresZrodlowy = ArkuszZrodlowy.Range("A7:M" & OstatniWiersz).SpecialCells(xlCellTypeVisible) 'wyznaczenie zakresu źródłowego

Set ZakresDocelowy = ArkuszDocelowy.Range("A7") 'wyzanczenie zakresu docelowego

ZakresZrodlowy.Copy Destination:=ZakresDocelowy 'skopiowanie danych z zakresu źródłowego do zakresu docelowego

ArkuszDocelowy.Columns("F:L").EntireColumn.Hidden = True 'ukrycie kolumnn zbędnych na liście płac

' Zapisywanie pliku wyjściowego

ArkuszDocelowy.Copy 'zapisanie arkusza z wygenerowaną tabelą dla danej jednostki

With ActiveSheet

.SaveAs Filename:=Katalog & "\Lista płac" & Jednostka.Value & ".xlsx"

.Parent.Close SaveChanges:=False ' dokonane zmiany nie są zapiwywane w arkuszu źródłowym

End With

Next Jednostka

' Czyszczenie danych celem pozostawienia szablonu bez zapisanych danych

If ArkuszDocelowy.Range("A7") <> "" Then

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).ClearContents ' wyczyszczenie zawartości

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).Borders.LineStyle = xlNone ' wyczyszczenie obramowania

End If

' Wyczyszczenie filtra

ArkuszZrodlowy.ListObjects("Tabela4").Range.AutoFilter Field:=2

ArkuszDocelowy.Columns("F:L").EntireColumn.Hidden = False 'odkrycie kolumn w arkuszu docelowym

' Zwolnienie zasobów obiektów FSO

Set FSO = Nothing

'wyświetlenie komunikatu

MsgBox "Wygenerowano listy płac dla jednostek w .xlsx" & vbNewLine & vbNewLine & "Listy płac zapisano w katalogu: Listy płac" & vbNewLine & vbNewLine & vbNewLine, vbInformation, "Informacja o listach płac"

Application.ScreenUpdating = True ' włączenie aktualizacji ekranu

End Sub

### Moduł: RaportyWord

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI). Praca z programami pakietu Microsoft Office.

Makro tworzy raporty w aplikacji Word z informacją o przydzielonych kwotach nagród dla poszczególnych grup pracowniczych w poszczególnych jednostkach organizacyjnych. Raporty generowane są na bazie uprzednio utworzonego szablonu w aplikacji Word.

'Microsoft Word

'Referencje: Tools --> References... --> Microsoft Word 16.0 Object Library

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

'FileSystemObject

'Referencje: Tools --> References... --> Windows Script Host Object Model

'......................................................................................

Sub Raport\_Word()

'Makro tworzy spersonalizowane raporty w Wordzie

'Deklaracja zmiennych

Dim WordA As Word.Application 'aplikacja Word

Dim PlikW As Word.Document 'plik Worda

Dim Nazwa As Word.Range 'obszar Worda ze zdefiniowaną nazwą

Dim Zakres As Range 'zakres

Dim NrRaportu As Long ' numer raportu

Dim Okres As Variant, Jednostka As Variant, Fundusz As Long, S8 As Long, S7 As Long, S6 As Long

Dim S5 As Long, S4 As Long, S3 As Long, S2 As Long, S1 As Long 'zmienne użyte w szablonie

Dim KwotaA As Long, KwotaB As Long ' zmienne użyte w szablonie

Dim Katalog As String 'lokalizacja zapisywanych raportów

Const PlikSzablon = "Szablon Word.docx" 'nazwa pliku Worda z szablonem

'Wczytanie danych

Set Zakres = ThisWorkbook.Sheets("Tabele pomocnicze").Range("D4:P18")

Katalog = ThisWorkbook.Path & "\Raporty dla jednostek\_" & Format(Date, "yyyy-mm-dd")

'Wczytanie nowego obiektu będącego aplikacją Worda

Set WordA = New Word.Application

WordA.Visible = True 'widoczna aplikacja Word

Application.ScreenUpdating = False ' włączenie aktualizacji ekranu

Application.EnableEvents = False ' wyłączenie obsługi zdarzeń

'Otwarcie szablonu (pliku Word)

Set PlikW = WordA.Documents.Open(ThisWorkbook.Path & "\" & PlikSzablon)

For NrRaportu = 1 To Zakres.Rows.Count 'generowanie raportów dla poszczególnych jednostek

Application.StatusBar = "Generowanie raportu: " & NrRaportu & "z" & Zakres.Rows.Count 'wyświetlenie postępu generowania raportów

'Jednostka

Jednostka = Zakres.Cells(NrRaportu, 1).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("Jednostka").Range 'przypisanie zakładki

Nazwa.Text = Jednostka

PlikW.Bookmarks.Add "Jednostka", Nazwa

'Okres

Okres = Zakres.Cells(NrRaportu, 2).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("Okres").Range 'przypisanie zakładki

Nazwa.Text = Okres

PlikW.Bookmarks.Add "Okres", Nazwa

'Fundusz nagród

Fundusz = Zakres.Cells(NrRaportu, 13).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("Fundusz").Range 'przypisanie zakładki

Nazwa.Text = Format(Fundusz, "#,##0.00")

PlikW.Bookmarks.Add "Fundusz", Nazwa

'S8

S8 = Zakres.Cells(NrRaportu, 3).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("S8").Range 'przypisanie zakładki

Nazwa.Text = Format(S8, "#,##0.00")

PlikW.Bookmarks.Add "S8", Nazwa

'S7

S7 = Zakres.Cells(NrRaportu, 4).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("S7").Range 'przypisanie zakładki

Nazwa.Text = Format(S7, "#,##0.00")

PlikW.Bookmarks.Add "S7", Nazwa

'S6

S6 = Zakres.Cells(NrRaportu, 6).Value 'wyznaczenie zakresu

Set Nazwa = PlikW.Bookmarks("S6").Range 'przypisanie zakładki

Nazwa.Text = Format(S6, "#,##0.00")

PlikW.Bookmarks.Add "S6", Nazwa

'S5

S5 = Zakres.Cells(NrRaportu, 7).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("S5").Range 'przypisanie zakładki

Nazwa.Text = Format(S5, "#,##0.00")

PlikW.Bookmarks.Add "S5", Nazwa

'S4

S4 = Zakres.Cells(NrRaportu, 8).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("S4").Range 'przypisanie zakładki

Nazwa.Text = Format(S4, "#,##0.00")

PlikW.Bookmarks.Add "S4", Nazwa

'S3

S3 = Zakres.Cells(NrRaportu, 9).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("S3").Range 'przypisanie zakładki

Nazwa.Text = Format(S3, "#,##0.00")

PlikW.Bookmarks.Add "S3", Nazwa

'S2

S2 = Zakres.Cells(NrRaportu, 10).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("S2").Range 'przypisanie zakładki

Nazwa.Text = Format(S2, "#,##0.00")

PlikW.Bookmarks.Add "S2", Nazwa

'S1

S1 = Zakres.Cells(NrRaportu, 11).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("S1").Range 'przypisanie zakładki

Nazwa.Text = Format(S1, "#,##0.00")

PlikW.Bookmarks.Add "S1", Nazwa

'KwotaA

KwotaA = Zakres.Cells(NrRaportu, 5).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("KwotaA").Range 'przypisanie zakładki

Nazwa.Text = Format(KwotaA, "#,##0.00")

PlikW.Bookmarks.Add "KwotaA", Nazwa

'KwotaB

KwotaB = Zakres.Cells(NrRaportu, 12).Value 'wyznaczenie statusu

Set Nazwa = PlikW.Bookmarks("KwotaB").Range 'przypisanie zakładki

Nazwa.Text = Format(KwotaB, "#,##0.00")

PlikW.Bookmarks.Add "KwotaB", Nazwa

'utworzenie katalogu do zapisu pliku

Dim FSO As Object

Set FSO = CreateObject("Scripting.FileSystemObject")

If Not FSO.FolderExists(Katalog) Then

' Katalog nie istnieje, a więc tworzenie katalogu

FSO.CreateFolder Katalog

End If

'Zapisanie i zamknięcie pliku

PlikW.SaveAs Filename:=Katalog & "\" & Jednostka & ".docx" 'zapisanie pliku w Wordzie

PlikW.ExportAsFixedFormat OutputFileName:=Katalog & "\" & Jednostka & ".pdf", ExportFormat:=wdExportFormatPDF, OpenAfterExport:=False 'zapisanie pliku w pdf

Next NrRaportu

Application.StatusBar = "" 'koniec wyświetlenia postępu generowania raportów

'zamknięcie szablonu raportu

PlikW.Close 'zamknięcie pliku

WordA.Quit 'zamknięcie aplikacji Word

' zwolnienie zasobów obiektów FSO

Set FSO = Nothing

'wyświetlenie komunikatu

MsgBox "Wygenerowano raporty dla jednostek w .docx i .pdf" & vbNewLine & vbNewLine & "Raporty zapisano w katalogu: Raporty dla jednostek" & vbNewLine & vbNewLine & vbNewLine, vbInformation, "Informacja o raportach"

Application.ScreenUpdating = True ' wyłączenie aktualizacji ekranu

Application.EnableEvents = True ' włączenie obsługi zdarzeń

End Sub

### Moduł: Statystyki

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI). Praca z programami pakietu Microsoft Office

Makro generuje statystyki dla wybranych kryteriów w aplikacji Power Point. Statystyki dotyczą:

* liczby dni roboczych absencji pracowniczych w badanym okresie;
* wysokości przyznanych nagród w poszczególnych jednostkach organizacyjnych;
* liczby pracowników obejmujących poszczególne stanowiska w określonych kategoriach.

'Obiekt: Microsoft PowerPoint

'Referencje: Tools --> References... --> Microsoft PowerPoint 16.0 Object Library

'.................................................................................

Sub Statystyki()

'Makro sprawdza czy istnieje katalog do zapisu raportów

Dim FSO As Object

Dim Katalog As String

'wczytanie lokalizacji katalogu

Katalog = ThisWorkbook.Path & "\Statystyki\_" & Format(Date, "yyyy-mm-dd")

'Utworzenie katalogu do zapisu pliku

Set FSO = CreateObject("Scripting.FileSystemObject")

If Not FSO.FolderExists(Katalog) Then

' Katalog nie istnieje, a więc tworzenie katalogu

FSO.CreateFolder Katalog

End If

'Makro tworzy prezentację w Power Poincie

'Deklaracja zmiennych

Dim PowerPointA As PowerPoint.Application 'obiekt PowerPoint.Application

Dim PrezentacjaPP As PowerPoint.Presentation 'prezentacja PowerPoint

Dim SlajdPP As PowerPoint.Slide 'slajd PowerPoint

Dim ShapePP As PowerPoint.Shape 'obraz wstawiony na slajdzie PowerPoint

Dim Zakres As Range 'zakres w Excelu z kopiowanymi komórkami

Dim Tytul As String 'tytuł slajdu

Const Plik\_szablon = "Szablon PowerPoint.pptx" 'wskazanie nazwy szablonu

Application.ScreenUpdating = False ' wyłączenie aktualizacji ekranu

'Wczytanie szablonu prezentacji PowerPoint

'wczytanie nowego obiektu będącego aplikacją PowerPoint

Set PowerPointA = New PowerPoint.Application

PowerPointA.Visible = True 'widoczna aplikacja PowerPoint

'otwarcie szablonu prezentacji PowerPoint

Set PrezentacjaPP = PowerPointA.Presentations.Open(ThisWorkbook.Path & "\Szablon\_PowerPoint.pptx")

'Slajd nr 1

Set SlajdPP = PrezentacjaPP.Slides(1)

SlajdPP.Shapes("Podtytuł 2").TextFrame.TextRange = Sheets("Tabele pomocnicze").Range("E4") 'wstawienie tytułu

'Slajd nr 2 (dla 3 slajdów)

Dim Nr As Long

For Nr = 1 To 3

'skopiowanie slajdu

PrezentacjaPP.Slides(2).Copy 'skopiowanie

PrezentacjaPP.Slides.Paste 2 + Nr 'wklejenie

Set SlajdPP = PrezentacjaPP.Slides(2 + Nr) 'wczytanie

'uzupełnienie slajdu:

'tytuł slajdu

SlajdPP.Shapes("Tytuł 1").TextFrame.TextRange = Sheets("Tabele pomocnicze").Range("A21")

'wstawienie wykresu

Worksheets("Tabele pomocnicze").ChartObjects(Nr).CopyPicture

DoEvents 'wykonaj wszystkie zdarzenia

SlajdPP.Shapes.Paste

Set ShapePP = SlajdPP.Shapes(SlajdPP.Shapes.Count)

With ShapePP

'pozycjonowanie wykresu do obiektu Wykres1

.LockAspectRatio = msoFalse 'odblokowanie wsp. proporcji

.Left = SlajdPP.Shapes("Wykres 1").Left

.Top = SlajdPP.Shapes("Wykres 1").Top

.Width = SlajdPP.Shapes("Wykres 1").Width

.Height = SlajdPP.Shapes("Wykres 1").Height

End With

SlajdPP.Shapes("Wykres 1").Delete 'usunięcie obiektu Wykres1

'wstawienie statystyk

Dim Statystyki As String 'statystyki

With Worksheets("Tabele pomocnicze")

Statystyki = \_

.Range("I" & 6 + 17 \* Nr) & vbTab & FormatNumber(.Range("J" & 6 + 17 \* Nr)) & vbNewLine & \_

.Range("I" & 8 + 17 \* Nr) & vbTab & vbTab & vbTab & FormatNumber(.Range("J" & 8 + 17 \* Nr)) & vbNewLine & \_

.Range("I" & 10 + 17 \* Nr) & vbTab & vbTab & FormatNumber(.Range("J" & 10 + 17 \* Nr)) & vbNewLine & \_

.Range("I" & 12 + 17 \* Nr) & vbTab & vbTab & FormatNumber(.Range("J" & 12 + 17 \* Nr)) & vbNewLine & \_

.Range("I" & 17 + 17 \* Nr) & vbTab & vbTab & FormatNumber(.Range("J" & 17 + 17 \* Nr)) & vbNewLine & \_

.Range("I" & 18 + 17 \* Nr) & vbTab & vbTab & FormatNumber(.Range("J" & 18 + 17 \* Nr)) & vbNewLine 'zakres danych

End With

SlajdPP.Shapes("Statystyki").TextFrame.TextRange = Statystyki 'wstawienie statystyk do PP

Next Nr

'Usunięcie formatki slajdu nr 2 i 5

PrezentacjaPP.Slides(2).Delete

PrezentacjaPP.Slides(5).Delete

'Zapisanie i zamknięcie pliku

PrezentacjaPP.SaveAs Filename:=Katalog & "\Nagrody -" & Format(Date, "YYYYMMDD") & ".pptx"

PowerPointA.ActivePresentation.Close

PowerPointA.Quit 'zamknięcie aplikacji Power Point

'Odznaczenie kopiowanego obszaru

Application.CutCopyMode = False

'wyświetlenie komunikatu

MsgBox "Wygenerowano prezentację przedstawiającą statystyki powiązane z przyznaniem nagród dla pracowników" \_

& vbNewLine & vbNewLine & "Prezentację zapisano w folderze: Statystyki" & vbNewLine & vbNewLine & vbNewLine, \_

vbInformation, "Informacja o statystykach"

Application.ScreenUpdating = True ' włączenie aktualizacji ekranu

End Sub

### Moduł: TabelaZbiorcza

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA.

Makro „TabelaZbiorcza” otwiera pliki z danymi poszczególnych jednostek organizacyjnych, kopiuje wyznaczone zakresy danych oraz zapisuje je po kolei w tabeli z arkusza „Tabela zbiorcza”.

Sub TabelaZbiorcza()

'Makro otwiera pliki w Excelu i kopiuje wyznaczone zakresy do arkusza "Tabela zbiorcza"

' Deklaracja zmiennych

Dim SkoroszytDocelowy As Workbook 'skoroszyt docelowy

Dim ArkuszDocelowy As Worksheet 'arkusz docelowy

Dim ŚcieżkaPliku As String 'ścieżka do plików źródłowych

Dim WierszDocelowy As Long 'wiersz w którym zakres danych zostanie wklejony

Dim SkoroszytŹródło As Workbook 'skoroszyt źródłowy

Dim ArkuszŹródło As Worksheet 'arkusz źródłowy

Dim OstatniWierszŹródło As Long 'ostatni wiersz z zakresu w arkuszu źródłowym

Dim WierszŹródło As Long

Dim i As Integer

' Ustawienie skoroszytu i arkusza docelowego

Set SkoroszytDocelowy = ThisWorkbook

Set ArkuszDocelowy = SkoroszytDocelowy.Worksheets("Tabela zbiorcza")

' Wyczyszczenie danych w arkuszu docelowym

ArkuszDocelowy.Rows("7:" & ArkuszDocelowy.Rows.Count).Delete

Application.ScreenUpdating = False ' wyłączenie aktualizacji ekranu

' Pętla otwierająca i kopiująca dane z plików

For i = 101 To 115

ŚcieżkaPliku = ThisWorkbook.Path & "\Tabele dla jednostek\" & i 'wskazanie ścieżki plików źródłowych

Set SkoroszytZrodlo = Workbooks.Open(ŚcieżkaPliku)

Set ArkuszZrodlo = SkoroszytZrodlo.Worksheets(1)

' Określenie ostatniego wiersza w źródłowym arkuszu

OstatniWierszŹródło = ArkuszZrodlo.Cells(Rows.Count, 1).End(xlUp).Row

' Kopiowanie danych z arkusza źródłowego do arkusza docelowego

WierszDocelowy = ArkuszDocelowy.Cells(Rows.Count, 1).End(xlUp).Row + 1

ArkuszZrodlo.Range("A7:M" & OstatniWierszŹródło).Copy Destination:=ArkuszDocelowy.Cells(WierszDocelowy, 1)

SkoroszytZrodlo.Close False

Next i

'wyświetlenie komunikatu

MsgBox "Wygenerowano tabelę zbiorczą dla jednostek w .xlsx" & vbNewLine & vbNewLine & "Tabelę zapisano w arkuszu: Tabela zbiorcza" & vbNewLine & vbNewLine & vbNewLine, vbInformation, "Informacja o tabeli zbiorczej"

Application.ScreenUpdating = True ' Wyłącz aktualizację ekranu

End Sub

### Moduł: Tabele

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA oraz TWORZENIE PROFESJONALNYCH APLIKACJI (WSPÓŁPRACA Z INNYMI PROGRAMAMI). Operacje na plikach.

Makro "Tabele" generuje osobne tabele z danymi dla poszczególnych jednostek organizacyjnych na podstawie danych zawartych w tabeli źródłowej. Każda tabela jest zapisywana jako osobny plik .xlsx w folderze "Tabele dla jednostek".

'FileSystemObjecy

'Referencje: Tools --> References... --> Windows Script Host Object Model

'......................................................................................

Sub Tabele()

'Makro generuje tabele dla poszczególnych jednostek na bazie tabeli źródłowej

Dim FSO As Object

Dim Katalog As String

Const PlikSzablon = "Tabela dla jednostek" 'nazwa arkusza Excela z szablonem

Katalog = ThisWorkbook.Path & "\Tabele dla jednostek" 'ścieżka katalogu

Application.DisplayAlerts = False ' ukrycie alertów

' utworzenie nowego folderu

Set FSO = CreateObject("Scripting.FileSystemObject")

If Not FSO.FolderExists(Katalog) Then

' Katalog nie istnieje, a więc tworzenie katalogu

FSO.CreateFolder Katalog

End If

Dim ArkuszZrodlowy As Worksheet 'arkusz źródłowy

Dim ArkuszDocelowy As Worksheet 'arkusz docelowy

Dim ZakresZrodlowy As Range 'zakres źródłowy

Dim ZakresDocelowy As Range 'zakres docelowy

Dim OstatniWiersz As Long 'ostatni wiersz

' Ustawienie arkuszy źródłowego i docelowego

Set ArkuszZrodlowy = ThisWorkbook.Worksheets("Tabela źródłowa")

Set ArkuszDocelowy = ThisWorkbook.Worksheets("Tabela dla jednostek")

' Określenie ostatniego wiersza z zakresu źródłowego

OstatniWiersz = ArkuszZrodlowy.Cells(Rows.Count, 1).End(xlUp).Row

'Znaleznienie unikalnych wartości w kolumnie 2 (jednostka organizacyjna)

Dim Jednostki As Range

Application.ScreenUpdating = False ' wyłączenie aktualizacji ekranu

'Skopiowanie unikalnych wartości z kolumny "B" do komórki "L6"

ArkuszZrodlowy.Range("B6:B" & OstatniWiersz).AdvancedFilter Action:=xlFilterCopy, CopyToRange:=ArkuszZrodlowy.Range("L6"), Unique:=True

'Przypisanie skopiowanych wartości do zmiennej

Set Jednostki = ArkuszZrodlowy.Range("L7:L21")

Dim Jednostka As Range ' jednostka

Dim Filtr As Range 'filtr

Dim OstatniWierszDocelowy As Long 'ostatni wiersz w arkuszu docelowym

'Pętla generująca tabele dla poszczególnych jednostek

For Each Jednostka In Jednostki

' Czyszczenie danych w arkuszu docelowym

If ArkuszDocelowy.Range("A7") <> "" Then

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).ClearContents ' wyczyszczenie zawartości

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).Borders.LineStyle = xlNone ' wyczyszczenie obramowania

End If

' Ustawienie filtra dla jednostki

ArkuszZrodlowy.Range("A6:F" & OstatniWiersz).AutoFilter Field:=2, Criteria1:=Jednostka.Value

' Skopiowanie widocznych danych dla jednostki

OstatniWierszDocelowy = ArkuszDocelowy.Cells(Rows.Count, 1).End(xlUp).Row + 1

Set ZakresZrodlowy = ArkuszZrodlowy.Range("A7:F" & OstatniWiersz).SpecialCells(xlCellTypeVisible)

Set ZakresDocelowy = ArkuszDocelowy.Range("A7")

ZakresZrodlowy.Copy Destination:=ZakresDocelowy

' Zapisanie pliku wyjściowego

ArkuszDocelowy.Copy

With ActiveSheet

.SaveAs Filename:=Katalog & "\" & Jednostka.Value & ".xlsx"

.Parent.Close SaveChanges:=False

End With

Next Jednostka

' Czyszczenie danych w szablonie w arkuszu docelowym

If ArkuszDocelowy.Range("A7") <> "" Then

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).ClearContents ' Wyczyszczenie zawartości

ArkuszDocelowy.Range(ArkuszDocelowy.Rows("7:7"), ArkuszDocelowy.Rows("7:7").End(xlDown)).Borders.LineStyle = xlNone ' Wyczyszczenie obramowania

End If

' Wyczyszczenie filtra

ArkuszZrodlowy.ListObjects("Tabela2").Range.AutoFilter Field:=2

' Ukrycie kolumny "L" na arkuszu "Tabela źródłowa"

ArkuszZrodlowy.Columns("L").Hidden = True

' Zwalnianie zasobów obiektów FSO

Set FSO = Nothing

'Wyświetlenie komunikatu

MsgBox "Wygenerowano tabele dla jednostek w .xlsx" & vbNewLine & vbNewLine & "Tabele zapisano w katalogu: Tabele dla jednostek" & vbNewLine & vbNewLine & vbNewLine, vbInformation, "Informacja o tabelach"

Application.ScreenUpdating = True ' włączenie aktualizacji ekranu

End Sub

### Moduł UserForm

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA oraz TWORZENIE PROFESJONALNYCH APLIKACJI (PROJEKTOWANIE INTERFEJSU UŻYTKOWNIKA).Zaawansowane formularze użytkownika.

Makro „UserForm” służy do zamknięcia wyświetlonego UserForma.

Sub ZamknijFormularz()

UserForm1.Hide ' zamykanie formularza

End Sub

### Moduł: Wyszukiwarka

Makro zastosowane w tym module przygotowane zostało na bazie zajęć pt. Excel i VBA - studia podyplomowe, Wydajna praca w VBA w programie MS Excel. Pętle VBA oraz TWORZENIE PROFESJONALNYCH APLIKACJI (PROJEKTOWANIE INTERFEJSU UŻYTKOWNIKA). Obiekty typu Shapes.

Makro "Wyszukiwarka" służy do efektywnego wyszukiwania danych w skoroszycie poprzez:

* sprawdzenie, czy komórka A17 w arkuszu "Wyszukiwarka" jest wypełniona (jeśli tak- wyczyszczenie zawartości i obramowania dla wierszy od 17 w dół);
* wczytanie danych z zakresu arkusza "Tabela źródłowa";
* filtrowanie arkusza źródłowego na podstawie kryteriów: wybranej jednostki organizacyjnej (komórka B7), komórki organizacyjnej (komórka D7) i stanowiska (komórka F7) (widoczne są jedynie wiersze spełniające wybrane kryteria);
* sprawdzenie, czy po zastosowaniu filtra istnieją widoczne komórki w zakresie danych (jeśli tak- skopiowanie do tabeli zaczynającej się od komórki A17 w arkuszu "Wyszukiwarka";
* wyłączenie filtra.

Makro "WywołajWyszukiwarkę" odpowiada za otwarcie arkusza "Wyszukiwarka" o ile taki arkusz istnieje w bieżącym skoroszycie. Oto opis poszczególnych kroków wykonywanych przez to makro:

Sub Wyszukiwarka()

'Makro pozwala na efektywne wyszukiwanie potrzebnych danych

' Deklaracja zmiennych

Dim ZakresDanych As Range 'zakres danych

Dim ZakresWidoczny As Range 'zakres wyszukanych danych

' Wyczyszczenie danych

If Worksheets("Wyszukiwarka").Range("A17") <> "" Then

Range(Rows("17:17"), Rows("17:17").End(xlDown)).ClearContents ' wyczyszczenie zawartości

Range(Rows("17:17"), Rows("17:17").End(xlDown)).Borders.LineStyle = xlNone ' wyczyszczenie obramowania

End If

' Wczytanie danych

Set ZakresDanych = Worksheets("Tabela źródłowa").Range("A6").CurrentRegion

' Filtrowanie arkusza żródłowego

With ZakresDanych

.AutoFilter Field:=2, Criteria1:=Worksheets("Wyszukiwarka").Range("B7") ' wybór jednostki organizacyjnej

.AutoFilter Field:=3, Criteria1:=Worksheets("Wyszukiwarka").Range("D7") ' wybór komórki organizacyjnej

.AutoFilter Field:=4, Criteria1:=Worksheets("Wyszukiwarka").Range("F7") ' wybór stanowiska

End With

' Sprawdzenie, czy istnieją widoczne komórki po zastosowaniu filtru

On Error Resume Next

Set ZakresWidoczny = ZakresDanych.SpecialCells(xlCellTypeVisible)

On Error GoTo 0

If Not ZakresWidoczny Is Nothing Then

' Skopiowanie widocznych komórek do tabeli dla jednostek

ZakresWidoczny.Copy Destination:=Worksheets("Wyszukiwarka").Range("A17")

End If

' Wyłączenie filtra

ZakresDanych.AutoFilter

End Sub

Sub WywołajWyszukiwarkę()

'Makro wywołujące arkusz Wyszukiwarka

Dim ArkuszWyszukiwarka As Worksheet

' Sprawdzenie, czy istnieje arkusz "Wyszukiwarka" w bieżącym skoroszycie

On Error Resume Next

Set ArkuszWyszukiwarka = ThisWorkbook.Worksheets("Wyszukiwarka")

On Error GoTo 0

' Jeżeli arkusz istnieje, odkryj go i przejdź do niego

If Not ArkuszWyszukiwarka Is Nothing Then

ArkuszWyszukiwarka.Visible = xlSheetVisible ' odkrycie ukrytego arkusza

ArkuszWyszukiwarka.Activate

Else

'wyświetlenie komunikatu

MsgBox "Arkusz ""Wyszukiwarka"" nie istnieje w bieżącym skoroszycie.", vbInformation

End If

End Sub